PerlMagick，Perl API

安装 • 概述 • 示例脚本 • 读取或写入图像 • 操作图像 • 设置图像属性 • 获取图像属性 • 将图像与重建图像进行比较 • 创建图像蒙太奇 • 使用 Blob • 直接访问图像像素 • 其他方法 • 处理异常 • 常量

PerlMagick 是一个面向对象的 Perl 接口，用于 ImageMagick。使用该模块可以在 Perl 脚本中读取、操作或写入图像或图像序列。这使得它非常适合 Web CGI 脚本。您的系统上必须安装 ImageMagick 6.5.5 或更高版本以及 Perl 5.005_02 或更高版本，才能正确构建 PerlMagick。

有一些有用的脚本可供使用，以向您展示 PerlMagick 的价值。您可以使用 MagickStudio 进行基于 Web 的图像操作和转换，或者使用 L-system 使用数学结构创建植物图像，最后浏览缩略图图像集合并选择要查看的图像，可以使用 WebMagick 图像导航器。

您可以在 ImageMagick Studio 的 Web 浏览器中试用 PerlMagick。或者，您可以查看 示例，了解选定的 PerlMagick 函数。

安装

UNIX

您的系统 RPM 存储库中是否有 PerlMagick？例如，在我们的 CentOS 系统上，我们这样安装 PerlMagick

yum install ImageMagick-perl

如果没有，您必须从 ImageMagick 源代码发行版中安装 PerlMagick。下载最新的 源代码 版本。

使用以下命令解压缩发行版

tar xvzf ImageMagick.tar.gz

接下来配置并编译 ImageMagick

$ cd ImageMagick-7.1.1
$ ./configure -with-perl
$ make

如果 ImageMagick/PerlMagick 在没有投诉的情况下配置和编译，那么您就可以将其安装到您的系统上了。安装需要管理员权限。要安装，请键入

sudo make install

您可能需要配置动态链接器运行时绑定

sudo ldconfig /usr/local/lib

最后，验证 PerlMagick 的安装是否成功，请键入

perl -MImage::Magick -le 'print Image::Magick->QuantumDepth'

恭喜您，您拥有一个可工作的 ImageMagick 发行版，并且可以开始使用 PerlMagick 来 转换、合成或编辑 您的图像。

Windows XP/Windows 2000

您的系统上必须已经安装 ImageMagick。此外，还需要 Windows 2000 的 ImageMagick 源代码发行版。您还必须拥有 Visual C++ 或 J++ 开发环境中的 nmake。将 \bin\IMagick.dll 和 \bin\X11.dll 复制到您的动态加载路径中的目录，例如 c:\perl\site\5.00502。

接下来，键入

cd PerlMagick
perl Makefile.nt
nmake
nmake install

运行回归测试

要验证安装是否正确，请键入

make test

在 Windows 下使用 nmake test。有一些演示脚本可供使用，以练习 PerlMagick 可以执行的许多函数。键入

使用 prove 实用程序从构建文件夹执行测试

prove --blib blib -I `pwd` -bv ./t/read.t

cd demo
make

现在您可以从 Perl 脚本中使用 PerlMagick 方法了。

概述

任何想要使用 PerlMagick 方法的脚本都必须首先在其命名空间内定义这些方法并实例化一个图像对象。使用以下方法进行此操作

use Image::Magick;

$image = Image::Magick->new;

PerlMagick 了解 quantum。您可以在实例化图像对象时请求特定的量子深度

use Image::Magick::Q16;

$image = Image::Magick::Q16->new;

new() 方法接受与 SetAttribute 相同的参数。例如，

$image = Image::Magick->new(size=>'384x256');

接下来您将想要读取图像或图像序列，操作它，然后显示或写入它。PerlMagick 的输入和输出方法在 读取或写入图像 中定义。有关影响图像读取或写入方式的方法，请参见 设置图像属性。有关转换图像的方法列表，请参考 操作图像。 获取图像属性 描述了如何检索图像的属性。有关将图像作为缩略图拼贴在背景上的详细信息，请参考 创建图像蒙太奇。最后，一些方法不适合任何上述类别。查看 其他方法，了解这些方法的列表。

完成 PerlMagick 对象后，您应该考虑销毁它。图像序列中的每个图像都存储在虚拟内存中。这可能会累计到兆字节的内存。销毁 PerlMagick 对象后，内存将被返回供其他 Perl 方法使用。销毁对象的推荐方法是使用 undef

undef $image;

要删除所有图像但保留 Image::Magick 对象，请使用

@$image = ();

最后，要从多图像序列中删除单个图像，请使用

undef $image->[$x];

下一节说明如何使用各种 PerlMagick 方法来操作图像序列。

一些 PerlMagick 方法需要外部程序，例如 Ghostscript。这可能需要在您的 PATH 环境变量中显式添加路径才能正常工作。例如（在 Linux 中），

$ENV{PATH}' . "='/../bin:/usr/bin:/usr/local/bin';

示例脚本

以下是一个示例脚本，可以帮助您入门

#!/usr/local/bin/perl
use Image::Magick;

my($image, $x);

$image = Image::Magick->new;
$x = $image->Read('girl.png', 'logo.png', 'rose.png');
warn "$x" if "$x";

$x = $image->Crop(geometry=>'100x100+100+100');
warn "$x" if "$x";

$x = $image->Write('x.png');
warn "$x" if "$x";

该脚本读取三个图像，裁剪它们，并将一个图像写入单个图像作为 GIF 动画序列。在许多情况下，您可能希望访问序列中的单个图像。下一个示例说明了如何执行此操作

#!/usr/local/bin/perl
use Image::Magick;

my($image, $p, $q);

$image = new Image::Magick;
$image->Read('x1.png');
$image->Read('j*.jpg');
$image->Read('k.miff[1, 5, 3]');
$image->Contrast();
for ($x = 0; $image->[$x]; $x++)
{
  $image->[$x]->Frame('100x200') if $image->[$x]->Get('magick') eq 'GIF';
  undef $image->[$x] if $image->[$x]->Get('columns') < 100;
}
$p = $image->[1];
$p->Draw(stroke=>'red', primitive=>'rectangle', points=>20,20 100,100');
$q = $p->Montage();
undef $image;
$q->Write('x.miff');

假设您想要从一个 100x100 像素的白色画布开始，中心有一个红色像素。试试这个

$image = Image::Magick->new;
$image->Set(size=>'100x100');
$image->ReadImage('canvas:white');
$image->Set('pixel[49,49]'=>'red');

在这里，我们将 (1,1) 处红色分量的强度降低一半

@pixels = $image->GetPixel(x=>1,y=>1);
$pixels[0]*=0.5;
$image->SetPixel(x=>1,y=>1,color=>\@pixels);

或者假设您想要将彩色图像转换为灰度

$image->Quantize(colorspace=>'gray');

让我们使用 Taipai TrueType 字体为图像添加标注

$text = 'Works like magick!';
$image->Annotate(font=>'kai.ttf', pointsize=>40, fill=>'green', text=>$text);

也许您想从图像中提取所有像素强度并将其写入 STDOUT

@pixels = $image->GetPixels(map=>'I', height=>$height, width=>$width, normalize=>true);
binmode STDOUT;
print pack('B*',join('',@pixels));

您可以使用 PerlMagick 对象做到的其他巧妙的事情包括

$i = $#$p"+1";   # return the number of images associated with object p
push(@$q, @$p);  # push the images from object p onto object q
@$p = ();        # delete the images but not the object p
$p->Convolve([1, 2, 1, 2, 4, 2, 1, 2, 1]);   # 3x3 Gaussian kernel

读取或写入图像

使用下面列出的方法来读取、写入或显示图像或图像序列

读取或写入方法

方法	参数	返回值	描述
读取	一个或多个文件名	读取的图像数量	读取图像或图像序列
写入	文件名	写入的图像数量	写入图像或图像序列
显示	服务器名称	显示的图像数量	将图像或图像序列显示到 X 服务器
动画	服务器名称	动画的图像数量	将图像序列动画到 X 服务器

为了方便起见，方法 Write()、Display() 和 Animate() 可以接受 SetAttribute 知道的任何参数。例如，

$image->Write(filename=>'image.png', compression=>'None');

使用 - 作为方法 Read() 的文件名，从标准输入读取，或作为方法 Write() 的文件名，写入标准输出

binmode STDOUT;
$image->Write('png:-');

要从 PERL 文件句柄中读取 GIF 格式的图像，请使用

$image = Image::Magick->new;
open(IMAGE, 'image.gif');
$image->Read(file=>\*IMAGE);
close(IMAGE);

要将 PNG 格式的图像写入 PERL 文件句柄，请使用

$filename = "image.png";
open(IMAGE, ">$filename");
$image->Write(file=>\*IMAGE, filename=>$filename);
close(IMAGE);

请注意，从 Perl 文件句柄中读取或写入可能在 Windows 下失败，因为 ImageMagick 和 ActiveState Perl 发行版之间的 C 运行时库版本不同，或者其中一个 DLL 与 /MT 选项链接。有关解释，请参见 跨 DLL 边界传递 CRT 对象时可能发生的错误。

如果文件名中出现 %0Nd、%0No 或 %0Nx，则将其解释为 printf 格式规范，并将规范替换为场景编号的指定十进制、八进制或十六进制编码。例如，

image%03d.miff

转换文件 image000.miff、image001.miff 等。

您可以选择在任何方法名称中添加 Image。例如，ReadImage() 是方法 Read() 的别名。

操作图像

使用例如 ReadImage() 方法创建图像后，您可能希望对其进行操作。以下是 PerlMagick 提供给您的所有图像操作方法的列表。有 示例 演示选定的 PerlMagick 方法。以下是如何调用图像操作方法的示例

$image->Crop(geometry=>'100x100+10+20');
$image->[$x]->Frame("100x200");

以下是您可以调用的其他图像操作方法的列表

请注意，geometry 参数是 width 和 height 参数的简写（例如，geometry=>'106x80' 等效于 width=>106, height=>80）。

您可以在 Annotate() 和 Draw() 中指定 @filename。这会从磁盘上的文件读取文本或图形基元指令。例如，

image->Draw(fill=>'red', primitive=>'rectangle',
 points=>'20,20 100,100  40,40 200,200  60,60 300,300');

等效于

$image->Draw(fill=>'red', primitive=>'@draw.txt');

其中 draw.txt 是磁盘上的一个文件，包含以下内容：

rectangle 20, 20 100, 100
rectangle 40, 40 200, 200
rectangle 60, 60 300, 300

方法 Annotate()、Comment()、Draw() 和 Label() 的 text 参数可以包含图像文件名、类型、宽度、高度或其他图像属性，方法是嵌入这些特殊格式字符

%b   file size
%c   comment
%d   directory
%e   filename extension
%f   filename
%g   page geometry
%h   height
%i   input filename
%k   number of unique colors
%l   label
%m   magick
%n   number of scenes
%o   output filename
%p   page number
%q   quantum depth
%r   image class and colorspace
%s   scene number
%t   top of filename
%u   unique temporary filename
%w   width
%x   x resolution
%y   y resolution
%z   image depth
%C   image compression type
%D   image dispose method
%H   page height
%Q   image compression quality
%T   image delay
%W   page width
%X   page x offset
%Y   page y offset
%@   bounding box
%#   signature
%%   a percent sign
\n   newline
\r   carriage return

例如，

text=>"%m:%f %wx%h"

为名为 bird.miff 的图像生成一个注释 MIFF:bird.miff 512x480，该图像的宽度为 512，高度为 480。

您可以选择将 Image 添加到任何方法名称中。例如，TrimImage() 是方法 Trim() 的别名。

上面列出的大多数属性在 magick 中都有类似项。有关这些属性的更详细说明，请参阅文档。

设置图像属性

使用 Set() 方法设置图像属性。例如，

$image->Set(dither=>'True');
$image->[$x]->Set(delay=>3);

本示例使用 'True'，而本文档中使用 '{True, False}'，您可以使用大小写不敏感的字符串 'True' 和 'False'，也可以使用整数 1 和 0。

在对布尔属性调用 Get() 时，Image::Magick 返回 1 或 0，而不是字符串。

以下是您可以设置的所有图像属性的列表

请注意，geometry 参数是 width 和 height 参数的简写（例如，geometry=>'106x80' 等效于 width=>106, height=>80）。

SetAttribute() 是 Set() 方法的别名。

上面列出的大多数属性在 magick 中都有类似项。有关这些属性的更详细说明，请参阅文档。

获取图像属性

使用 Get() 方法获取图像属性。例如，

($a, $b, $c) = $image->Get('colorspace', 'magick', 'adjoin');
$width = $image->[3]->Get('columns');

除了 设置图像属性 中列出的所有属性外，您还可以获取以下附加属性

GetAttribute() 是 Get() 方法的别名。

上面列出的大多数属性在 magick 中都有类似项。有关这些属性的更详细说明，请参阅文档。

将图像与其重建进行比较

使用 Compare() 方法数学和视觉地注释图像与其重建之间的差异。该方法支持以下参数

比较参数

参数	值	描述
channel	double	选择图像通道，默认情况下为除 alpha 之外的所有通道。
fuzz	double	在此距离内的颜色被视为相等
image	image-reference	图像重建
metric	AE、MAE、MEPP、MSE、PAE、PSNR、RMSE	使用此指标衡量图像之间的差异

在此示例中，我们将 ImageMagick 徽标与其锐化重建进行比较

use Image::Magick;

$logo=Image::Magick->New();
$logo->Read('logo:');
$sharp=Image::Magick->New();
$sharp->Read('logo:');
$sharp->Sharpen('0x1');
$difference=$logo->Compare(image=>$sharp, metric=>'rmse');
print $difference->Get('error'), "\n";
$difference->Display();

除了报告的均方根误差约为 0.024 之外，还会显示差异图像，以便您可以直观地识别图像之间的差异。

创建图像蒙太奇

使用 Montage() 方法通过组合多个独立图像来创建合成图像。图像在合成图像上平铺，图像的名称可以选择性地出现在每个图块的正下方。例如，

$image->Montage(geometry=>'160x160', tile=>'2x2', texture=>'granite:');

以下是您可以设置的 Montage() 参数列表

请注意，geometry 参数是 width 和 height 参数的简写（例如，geometry=>'106x80' 等效于 width=>106, height=>80）。

MontageImage() 是 Montage() 方法的别名。

上面列出的大多数属性在 montage 中都有类似的属性。有关这些属性的更详细描述，请参阅文档。

处理 Blob

Blob 包含直接表示内存中而不是磁盘上的特定图像格式的数据。PerlMagick 支持所有这些图像 格式 中的 blob，并提供将 blob 转换为或从特定图像格式转换的方法。

Blob 方法

方法	参数	返回值	描述
ImageToBlob	任何图像 属性	相应图像格式中的图像数据数组	将图像或图像序列转换为 blob 数组
BlobToImage	一个或多个 blob	转换为图像的 blob 数量	将一个或多个 blob 转换为图像

ImageToBlob() 返回其各自格式的图像数据。然后，您可以打印它、将其保存到 ODBC 数据库、将其写入文件或将其传递到显示程序

@blobs = $image->ImageToBlob();
open(DISPLAY,"| display -") || die;
binmode DISPLAY;
print DISPLAY $blobs[0];
close DISPLAY;

BlobToImage() 方法返回从提供的 blob 转换的图像或图像序列

@blob=$db->GetImage();
$image=Image::Magick->new(magick=>'jpg');
$image->BlobToImage(@blob);

直接访问图像像素

使用这些方法可以直接访问图像像素

直接访问图像像素

方法	参数	描述
GetAuthenticPixels	geometry=>geometry, width=>integer, height=>integer, x=>integer, y=>integer	返回真实像素作为 C 指针
GetVirtualPixels	geometry=>geometry, width=>integer, height=>integer, x=>integer, y=>integer	返回虚拟像素作为 const C 指针
GetAuthenticIndexQueue		返回调色板索引或黑色像素作为 C 指针
GetVirtualIndexQueue		返回调色板索引或黑色像素作为 const C 指针
SyncAuthenticPixels		将真实像素同步到像素缓存

其他方法

Append() 方法追加一组图像。例如，

$p = $image->Append(stack=>{true,false});

追加与对象 $image 关联的所有图像。默认情况下，图像从左到右堆叠。将 stack 设置为 True 以将其从上到下堆叠。

Clone() 方法复制一组图像。例如，

$q = $p->Clone();

将对象 $p 中的所有图像复制到 $q。您可以将此方法用于单个或多个图像序列。

Coalesce() 合成一组图像，同时尊重任何页面偏移量和处置方法。GIF、MIFF 和 MNG 动画序列通常从图像背景开始，每个后续图像的大小和偏移量都不同。返回一个新的图像序列，其中所有图像都与第一个图像的虚拟画布大小相同，并且与序列中的下一个图像合成。例如，

$q = $p->Coalesce();

ComplexImages() 方法对图像序列执行复杂的数学运算。例如，

$p = $image->ComplexImages('conjugate');

EvaluateImages() 方法将算术、逻辑或关系表达式应用于一组图像。例如，

$p = $image->EvaluateImages('mean');

对与对象 $image 关联的所有图像进行平均。

Features() 方法返回图像中每个通道的特征，这些特征是在四个方向（水平、垂直、左对角线和右对角线）上以指定距离进行的。这些特征包括角动量、对比度、相关性、平方和：方差、逆差矩、总平均值、总方差、总熵、熵、差值方差、差值熵、相关信息度量 1、相关信息度量 2 以及最大相关系数。值以 RGB、CMYK、RGBA 或 CMYKA 顺序排列（取决于图像类型）。

@features = $image->Features(1);

Flatten() 方法展平一组图像并返回它。例如，

$p = $images->Flatten(background=>'none');
$p->Write('flatten.png');

图像序列被一个单个图像所取代，该图像是在第一个图像上合成第一个图像之后的每个图像而创建的。

Fx() 方法将数学表达式应用于一组图像并返回结果。例如，

$p = $image->Fx(expression=>'(g+b)/2.0',channel=>'red');
$p->Write('fx.miff');

将红色通道替换为绿色和蓝色通道的平均值。

有关此方法的详细讨论，请参阅 FX，特殊效果图像运算符。

Histogram() 返回图像中唯一的颜色以及每个颜色的计数。返回的值是红色、绿色、蓝色、不透明度和计数值的数组。

Morph() 方法变形一组图像。图像像素和大小都进行线性插值，以呈现从一个图像到下一个图像的变形外观

$p = $image->Morph(frames=>integer);

其中 frames 是要生成的中间图像数。默认为 1。

Mosaic() 从图像序列创建马赛克。

Mogrify() 方法是图像操作方法的单一入口点 (操作图像)。参数是方法的名称，后面跟着方法可能需要的任何参数。例如，以下调用是等效的

$image->Crop('340x256+0+0');
$image->Mogrify('crop', '340x256+0+0');

MogrifyRegion() 方法将转换应用于图像的区域。它类似于 Mogrify()，但从区域几何形状开始。例如，假设您想在位置 (40, 50) 处亮起图像的 100x100 区域

$image->MogrifyRegion('100x100+40+50', 'modulate', brightness=>50);

PerceptualHash() 将视觉上相同的图像映射到相同或相似的哈希值 - 在图像检索、身份验证、索引或复制检测以及数字水印中很有用。对于每个通道以及 sRGB 和 HCLp 色彩空间，将返回 7 个哈希值。例如，对于 sRGB 图像，预计会有 42 个感知哈希值。

@phash = $image->PerceptualHash();

Ping() 是一个便利方法，它返回有关图像的信息，而无需将图像读入内存。它返回图像的宽度、高度、以字节为单位的文件大小以及图像的格式。您可以指定多个文件名，但只能指定一个文件句柄

($width, $height, $size, $format) = $image->Ping('logo.png');
($width, $height, $size, $format) = $image->Ping(file=>\*IMAGE);
($width, $height, $size, $format) = $image->Ping(blob=>$blob);

这是查询图像是否存在及其特征的更有效且内存占用更少的方法。

Poly() 从图像序列以及相应的项（系数和次数对）构建多项式

$p = $image->Poly([0.5,1.0,0.25,2.0,1.0,1.0]);

PreviewImage() 将指定图像的 9 个缩略图平铺，并在不同强度下应用图像处理操作。这可能有助于确定特定图像处理操作的适当参数。从以下操作中选择：Rotate、Shear、Roll、Hue、Saturation、Brightness、Gamma、Spiff、Dull、Grayscale、Quantize、Despeckle、ReduceNoise、AddNoise、Sharpen、Blur、Threshold、EdgeDetect、Spread、Solarize、Shade、Raise、Segment、Swirl、Implode、Wave、OilPaint、CharcoalDrawing、JPEG。以下是一个示例

$preview = $image->Preview('Gamma');
$preview->Display();

要完全控制文本定位，您需要字体度量信息。使用

($x_ppem, $y_ppem, $ascender, $descender, $width, $height, $max_advance) =
  $image->QueryFontMetrics(parameters);

其中 parameters 是 Annotate 方法的任何参数。返回值为

1. 字符宽度
2. 字符高度
3. 升高
4. 下降
5. 文本宽度
6. 文本高度
7. 最大水平前进
8. 边界：x1
9. 边界：y1
10. 边界：x2
11. 边界：y2
12. 原点：x
13. 原点：y

使用 QueryMultilineFontMetrics() 获取多行文本的最大文本宽度和高度。

在不带参数的情况下调用 QueryColor() 以返回已知颜色名称的列表，或者指定一个或多个颜色名称以获取以下属性：红色、绿色、蓝色和不透明度值。

@colors = $image->QueryColor();
($red, $green, $blue) = $image->QueryColor('cyan');
($red, $green, $blue, $alpha) = $image->QueryColor('#716baeff');

QueryColorname() 接受颜色值并返回其相应的名称或十六进制值；

$name = $image->QueryColorname('rgba(80,60,0,0)');

在不带参数的情况下调用 QueryFont() 以返回已知字体的列表，或者指定一个或多个字体名称以获取以下属性：字体名称、描述、系列、样式、拉伸、粗细、编码、铸造厂、格式、度量和字形值。

@fonts = $image->QueryFont();
$weight = ($image->QueryFont('Helvetica'))[5];

在不带参数的情况下调用 QueryFormat() 以返回已知图像格式的列表，或者指定一个或多个格式名称以获取以下属性：附加、Blob 支持、原始、解码器、编码器、描述和模块。

@formats = $image->QueryFormat();
($adjoin, $blob_support, $raw, $decoder, $encoder, $description, $module) =
  $image->QueryFormat('gif');

使用 MagickToMime() 和图像格式名称获取其 MIME 类型，例如从 tif 获取 image/tiff。

$mime = $image->MagickToMime('tif');

使用 RemoteCommand() 向正在运行的 display 或 animate 应用程序发送命令。唯一的参数是要显示或动画的图像文件的名称。

$image->RemoteCommand('image.jpg');

Smush() 方法将一组图像合并在一起。例如，

$p = $image->Smush(stack=>{true,false},offset=>integer);

将与对象 $image 关联的所有图像合并在一起。默认情况下，图像从左到右合并。将 stack 设置为 True 以将其从上到下合并。

Statistics() 返回图像中每个通道的图像统计信息。返回的值是深度、最小值、最大值、平均值、标准差、峰度、偏度和熵值的数组，以 RGB、CMYK、RGBA 或 CMYKA 顺序排列（取决于图像类型）。

@statistics = $image->Statistics();

最后，Transform() 方法接受用于裁剪或调整大小一个或多个图像的完全限定的几何规范。例如，

$p = $image->Transform(crop=>'100x100+0+0');

您可以在上述任何方法名称中选择性地添加 Image。例如，PingImage() 是 Ping() 方法的别名。

处理异常

所有 PerlMagick 方法在成功时都返回一个未定义的字符串上下文。如果出现任何问题，错误将作为包含嵌入式数字状态码的字符串返回。状态码小于 400 则表示警告。这意味着操作未完成，但可以在某种程度上恢复。数字代码大于或等于 400 则表示错误，并指示操作完全失败。以下是不同方法返回异常的方式

返回数字的方法（例如 Read()、Write()）

$x = $image->Read(...);
warn "$x" if "$x";      # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number
print 0+$x;             # print the number of images read

对图像进行操作的方法（例如 Resize()、Crop()）

$x = $image->Crop(...);
warn "$x" if "$x";      # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number

返回图像的方法（EvaluateSequence()、Montage()、Clone()）应该用这种方式检查错误

$x = $image->Montage(...);
warn "$x" if !ref($x);  # print the error message
$x =~ /(\d+)/;
print $1;               # print the error number

这是一个示例错误消息

Error 400: Memory allocation failed

查看完整的错误和警告代码列表。

以下说明了如何使用数字状态代码

$x = $image->Read('rose.png');
$x =~ /(\d+)/;
die "unable to continue" if ($1 == ResourceLimitError);

常量

PerlMagick 包含这些常量

BlobError
BlobWarning
CacheError
CacheWarning
CoderError
CoderWarning
ConfigureError
ConfigureWarning
CorruptImageError
CorruptImageWarning
DelegateError
DelegateWarning
DrawError
DrawWarning
ErrorException
FatalErrorException
FileOpenError
FileOpenWarning
ImageError
ImageWarning
MissingDelegateError
MissingDelegateWarning
ModuleError
ModuleWarning
Opaque
OptionError
OptionWarning
QuantumDepth
QuantumRange
RegistryError
RegistryWarning
ResourceLimitError
ResourceLimitWarning
StreamError
StreamWarning
Success
Transparent
TypeError
TypeWarning
WarningException
XServerError
XServerWarning

您可以像这样访问它们

Image::Magick->QuantumDepth